Shader "Amplify Texture/Legacy Shaders/Reflective/Parallax Diffuse" {
Properties {
	_Color ("Main Color", Color) = (1,1,1,1)
	_ReflectColor ("Reflection Color", Color) = (1,1,1,0.5)
	_Parallax ("Height", Range (0.005, 0.08)) = 0.02
	_MainTex ("Base (RGB) RefStrength (A)", 2D) = "white" {}
	_Cube ("Reflection Cubemap", Cube) = "_Skybox" {}
	_BumpMap ("Normalmap", 2D) = "bump" {}
	_ParallaxMap ("Heightmap (A)", 2D) = "black" {}
	[HideInInspector] _VTInfoBlock( "VT (auto)", Vector ) = ( 0, 0, 0, 0 )
}
SubShader {
	Tags { "RenderType"="Opaque" "Amplify"="True" }
	LOD 500

CGPROGRAM
#pragma surface surf Lambert
#pragma target 3.0
#pragma glsl
#pragma multi_compile _ _VT_SINGLE_MODE
#include "Shared.cginc"

sampler2D _MainTex;
sampler2D _BumpMap;
samplerCUBE _Cube;
sampler2D _ParallaxMap;

fixed4 _Color;
fixed4 _ReflectColor;
float _Parallax;

struct Input {
	float2 uv_MainTex;
	float3 worldRefl;
	float3 viewDir;
	INTERNAL_DATA
};

void surf (Input IN, inout SurfaceOutput o) {
	half h = tex2D (_ParallaxMap, IN.uv_MainTex.xy).w;
	float2 offset = ParallaxOffset (h, _Parallax, IN.viewDir);
	IN.uv_MainTex += offset;

	VirtualCoord vcoord = VTComputeVirtualCoord( IN.uv_MainTex.xy );
	fixed4 tex = VTSampleAlbedo( vcoord );
	fixed4 c = tex * _Color;
	o.Albedo = c.rgb;

	o.Normal = UnpackNormal(VTSampleNormal( vcoord ));

	float3 worldRefl = WorldReflectionVector (IN, o.Normal);
	fixed4 reflcol = texCUBE (_Cube, worldRefl);
	reflcol *= tex.a;
	o.Emission = reflcol.rgb * _ReflectColor.rgb;
	o.Alpha = reflcol.a * _ReflectColor.a;
}
ENDCG
}

FallBack "Amplify Texture/Legacy Shaders/Reflective/Bumped Diffuse"
CustomEditor "VirtualMaterialEditor"
}
