Shader "Amplify Texture/Legacy Shaders/Nature/Terrain/Bumped Specular" {
Properties {
	_Color ("Main Color", Color) = (1,1,1,1)
	_SpecColor ("Specular Color", Color) = (0.5, 0.5, 0.5, 1)
	_Shininess ("Shininess", Range (0.03, 1)) = 0.078125
	_MainTex ("Base (RGB) Gloss (A)", 2D) = "white" {}
	_BumpMap ("Normalmap", 2D) = "bump" {}
	[HideInInspector] _VTInfoBlock( "VT (auto)", Vector ) = ( 0, 0, 0, 0 )
}

SubShader {
	Tags {
		"Amplify"="True"
		"AmplifyTerrain" = "True"
		"Queue" = "Geometry-100"
		"RenderType" = "Opaque"
	}
CGPROGRAM
#pragma surface surf BlinnPhong vertex:vert
#pragma target 3.0
#pragma glsl
#pragma multi_compile _ _VT_SINGLE_MODE
#include "../../Shared.cginc"

void vert (inout appdata_full v)
{
	v.tangent.xyz = cross(v.normal, float3(0,0,1));
	v.tangent.w = -1;
}

struct Input {
	float2 uv_MainTex;
};

sampler2D _MainTex;
fixed4 _Color;
half _Shininess;

void surf (Input IN, inout SurfaceOutput o) {
	VirtualCoord vcoord = VTComputeVirtualCoord( float2( IN.uv_MainTex.x, 1 - IN.uv_MainTex.y ) );
	fixed4 tex = VTSampleAlbedo( vcoord );
	o.Albedo = tex.rgb * _Color.rgb;
	o.Gloss = tex.a;
	o.Alpha = tex.a * _Color.a;
	o.Specular = _Shininess;
	o.Normal = UnpackNormal( VTSampleNormal( vcoord ) );
}
ENDCG
}

Dependency "AddPassShader" = "Hidden/Amplify Texture/Legacy Shaders/Nature/Terrain/Bumped Specular AddPass"
Dependency "BaseMapShader" = "Amplify Texture/Legacy Shaders/Nature/Terrain/Bumped Specular"

Fallback "Amplify Texture/Legacy Shaders/Nature/Terrain/Diffuse"

CustomEditor "VirtualMaterialEditor"
}
