Shader "Amplify Texture/Legacy Shaders/Self-Illumin/Parallax Specular" {
Properties {
	_Color ("Main Color", Color) = (1,1,1,1)
	_SpecColor ("Specular Color", Color) = (0.5, 0.5, 0.5, 1)
	_Shininess ("Shininess", Range (0.01, 1)) = 0.078125
	_Parallax ("Height", Range (0.005, 0.08)) = 0.02
	_MainTex ("Base (RGB) Gloss (A)", 2D) = "white" {}
	_Illum ("Illumin (A)", 2D) = "white" {}
	_BumpMap ("Normalmap", 2D) = "bump" {}
	_ParallaxMap ("Heightmap (A)", 2D) = "black" {}
	_Emission ("Emission (Lightmapper)", Float) = 1.0
	[HideInInspector] _VTInfoBlock( "VT (auto)", Vector ) = ( 0, 0, 0, 0 )
}
SubShader {
	Tags { "RenderType"="Opaque" "Amplify"="True" }
	LOD 600

CGPROGRAM
#pragma surface surf BlinnPhong
#pragma target 3.0
#pragma glsl
#pragma multi_compile _ _VT_SINGLE_MODE
#include "Shared.cginc"

sampler2D _MainTex;
sampler2D _BumpMap;
sampler2D _ParallaxMap;
sampler2D _Illum;
fixed4 _Color;
float _Parallax;
half _Shininess;
fixed _Emission;

struct Input {
	float2 uv_MainTex;
	float2 uv_Illum;
	float3 viewDir;
};

void surf (Input IN, inout SurfaceOutput o) {
	half h = tex2D (_ParallaxMap, IN.uv_MainTex).w;
	float2 offset = ParallaxOffset (h, _Parallax, IN.viewDir);
	IN.uv_MainTex += offset;
	IN.uv_Illum += offset;

	VirtualCoord vcoord = VTComputeVirtualCoord( IN.uv_MainTex.xy );
	fixed4 tex = VTSampleAlbedo( vcoord );
	fixed4 c = tex * _Color;
	o.Albedo = c.rgb;
	o.Gloss = tex.a;
	o.Emission = c.rgb * tex2D(_Illum, IN.uv_Illum).a;
#if defined (UNITY_PASS_META)
	o.Emission *= _Emission.rrr;
#endif
	o.Specular = _Shininess;
	o.Alpha = c.a;
	o.Normal = UnpackNormal(VTSampleNormal( vcoord ));
}
ENDCG
}
FallBack "Amplify Texture/Legacy Shaders/Self-Illumin/Bumped Specular"
CustomEditor "VirtualMaterialEditor"
}
